Guía

Cómo hacer un formato de cotización en Excel

Por Reporte Ágil ·Publicada el 14 de octubre de 2026

Un formato de cotización en Excel lleva tus datos y los del cliente, folio, fecha y vigencia, una tabla de partidas donde cada importe es cantidad × precio, y abajo subtotal, descuento, IVA y total. El IVA se calcula sobre el subtotal menos el descuento. Para enviarla, fija el área de impresión, ajústala a una página y guárdala en PDF.

Formato de cotización de una página con logo, partidas, IVA y total · plantilla Cotizador + Ventas y Clientes, con datos de demostración

Qué debe llevar una cotización

Tus datos: nombre o razón social, logo, teléfono, correo y, si facturas, tu RFC o ID fiscal.
Datos del cliente: nombre, contacto y, si te lo piden, su RFC y dirección.
Folio, fecha y vigencia: un folio único (COT-0001, COT-0002…) para encontrarla después, y hasta cuándo respetas el precio.
Partidas: descripción, unidad, cantidad, precio unitario e importe de cada producto o servicio.
Totales: subtotal, descuento, IVA y total, con la moneda.
Condiciones: forma de pago (por ejemplo, 50% de anticipo), tiempo de entrega y lo que no incluye.
Firma de aceptación del cliente, si trabajas sobre pedido.

Paso 1. El encabezado

Reserva las primeras filas para el logo (Insertar → Imágenes) y tus datos a la izquierda, y el título «COTIZACIÓN» con folio, fecha y vigencia a la derecha. La vigencia se calcula sola a partir de la fecha:

G4  =G3+15        válida hasta: 15 días después de la fecha en G3

Debajo, un bloque con los datos del cliente. Combina celdas solo en el encabezado; en la tabla de partidas complican copiar y ordenar.

Paso 2. La tabla de partidas

Una fila por producto o servicio, con estas columnas: # (A), descripción (B), unidad (C), cantidad (D), precio unitario (E) e importe (F). Si las partidas van de la fila 12 a la 26:

F12  =SI(D12="", "", D12*E12)

El SI deja la celda en blanco cuando la fila está vacía, para que el formato impreso no se llene de ceros. Copia la fórmula hacia abajo hasta la última fila.

Paso 3. Subtotal, descuento, IVA y total

F28  =SUMA(F12:F26)          subtotal
F29  =F28*E29                descuento (el porcentaje va en E29)
F30  =(F28-F29)*0.16         IVA: sobre el subtotal menos el descuento
F31  =F28-F29+F30            total

Pon la tasa en una celda aparte (por ejemplo, Configuración!B2 = 16%) y usa =(F28-F29)*Configuración!B2: así sirve si vendes en la franja fronteriza (8%) o en otro país. Si algún producto está exento, calcula el IVA por partida en una columna oculta y suma esa columna.

Paso 4. Precios desde un catálogo

Escribir el precio en cada cotización lleva a errores. Haz una hoja Productos con nombre (A), unidad (B) y precio (C), pon una lista desplegable en la columna de descripción (Datos → Validación de datos → Lista) y trae el precio con:

E12  =SI.ERROR(BUSCARV(B12, Productos!A:C, 3, FALSO), "")

FALSO pide coincidencia exacta; sin él, BUSCARV puede devolver el precio de otro producto. Si tu Excel separa argumentos con punto y coma, cambia las comas.

Cuidado con los precios que cambian. Si el precio sale del catálogo con una fórmula y después lo subes, cambian también las cotizaciones que ya enviaste. Guarda siempre el PDF que mandas y, si llevas un registro en el mismo archivo, copia el precio como valor (Pegado especial → Valores) una vez enviada la cotización, o registra los cambios de precio con su fecha.

Para registrarlos, haz una hoja Cambios con producto (A), fecha desde la que aplica (B) y precio nuevo (C), y nunca cambies el precio en Productos. Con la fecha de la cotización en G3, una columna auxiliar (H) busca el último cambio hasta esa fecha y E12 toma su precio, o el del catálogo si no hay:

H12  =MAX.SI.CONJUNTO(Cambios!B:B, Cambios!A:A, B12, Cambios!B:B, "<="&$G$3)
E12  =SI(B12="", "", SI(H12=0, SI.ERROR(BUSCARV(B12, Productos!A:C, 3, FALSO), ""), SUMAR.SI.CONJUNTO(Cambios!C:C, Cambios!A:A, B12, Cambios!B:B, H12)))

Así una cotización de enero conserva el precio de enero aunque en marzo lo subas. No registres dos cambios del mismo producto con la misma fecha, porque SUMAR.SI.CONJUNTO los sumaría. Oculta la columna H o déjala fuera del área de impresión. MAX.SI.CONJUNTO existe en Excel 2019, Microsoft 365 y Google Sheets.

Paso 5. Una página en PDF

Selecciona el rango de la cotización y fíjalo en Diseño de página → Área de impresión → Establecer área de impresión.
En Diseño de página → Ajustar área de impresión, pon 1 página de ancho por 1 de alto, orientación vertical y tamaño Carta.
Archivo → Exportar → Crear PDF (o Guardar como → PDF).

En Google Sheets: Archivo → Imprimir, «Hoja actual», vertical y «Ajustar a la página». Sheets imprime desde la celda A1, así que deja la cotización desde ahí y no pongas notas de uso arriba.

Paso 6. Lleva un registro de tus cotizaciones

Copiar la hoja para cada cotización funciona con pocas, pero no te dice cuánto cotizaste ni cuántas cerraste. Un registro con una fila por cotización (folio, fecha, cliente, total y estatus: Enviada, Aceptada, Rechazada, Vencida o Sustituida) te permite medir tu tasa de cierre:

=CONTAR.SI(H:H, "Aceptada") / (CONTAR.SI(H:H, "Enviada") + CONTAR.SI(H:H, "Aceptada") + CONTAR.SI(H:H, "Rechazada") + CONTAR.SI(H:H, "Vencida"))

La fórmula deja fuera las sustituidas: una cotización que reemplazaste por una versión nueva no es una venta perdida, y contarla bajaría tu tasa de cierre. Por lo mismo, no la sumes en lo cotizado del mes.

Y con la fecha de vigencia puedes ver cuáles vencen esta semana para llamar al cliente antes de que se enfríen.

Errores comunes

Calcular el IVA sobre el subtotal sin restar el descuento. El IVA va sobre lo que realmente cobras.
Folios repetidos. Usa un consecutivo y no reutilices folios de cotizaciones canceladas.
Sin vigencia. Si tus costos suben, una cotización sin fecha límite te obliga a respetar un precio viejo.
Editar la cotización que ya enviaste. Si el cliente pide cambios, haz otra con folio nuevo y marca la anterior como Sustituida, con el folio que la reemplaza: así sabes qué precio le diste en cada momento.
Montos en otra moneda sin decirlo. Escribe la moneda junto al total.

Si prefieres no armarlo desde cero

La plantilla Cotizador + Ventas y Clientes arma la cotización con tu logo en una página Carta o A4 al elegir el folio: hasta 25 partidas con precio del catálogo o precio especial, descuento, IVA configurable y condiciones. Cada partida toma el precio y la tasa de impuesto vigentes en la fecha de la cotización (hoja Cambios de precio), así subir tus precios no cambia lo que ya cotizaste, y al hacer una versión nueva la anterior pasa sola a Sustituida. Además lleva el registro de 1,000 cotizaciones con estatus y vencimiento automático, clientes, productos, ventas y cobros, una hoja de seguimiento y un dashboard con tu tasa de cierre. Es un archivo de Excel sin macros con su copia para Google Sheets.